list of dots Digital Research Alliance of Canada logo  NSERC logo  University of Ottawa logo / Université d'Ottawa

User Manual    [Previous]   [Next]   

Co-Op Education

Requirements for a University System to Manage Co-Op Programs

The co-op system works as follows. Employers contact the university and list potential jobs. Each job has a description, employer, location, start and end date, and a list of programs (e.g. SEG, CSI, MCG) for which it is applicable.

Each student in the system has a name, student number, list of available time slots (when they are not in courses, or not doing interviews), resume and transcript.

Students in various programs apply for jobs. Students choose a set of jobs they are interested in. The system shows the list of interested students to employers, and employers pick a set of students to interview. The system sets interview times that match the employee’s and student’s availability (set of available time slots).

At the end of the process, the system arranges for the employer to offer each job to a student. If the first student does not accept, the system arranges for other students (the employer’s second, third choices, etc. ) to be offered the job.

Example

// UML class diagram in Umple showing the data managed by
// a co-operative education system that has to place students with employers

class Program
{
  name;
  1..* -- * Student;
}

class Application
{
  * -- 1 Student;
  * -- 1 Job;
  1..* -- 0..1 Interview;
  1 -- 0..1 Offer;
}

class Job
{
  description;
  location;
  Date startDate;
  Date endDate;
  * -- 1..* Program;
}

class Employer
{
  name;
  1 -- * Job;
  0..1 -> * TimeSlot;
}

class Interview
{
  location;
  0..1 -> 0..1 TimeSlot;
}

class TimeSlot
{
  startTime;
  endTime;
  status;
}

class Student
{
  Integer stNum;
  1 -- 1 Transcript;
  0..1 -> * TimeSlot;
}

class Resume
{
  text;
  0..1 -- 1 Student;
}

class Transcript
{
  text;
}

class Offer
{
  ranking;
  Boolean accepted;
}


      

Load the above code into UmpleOnline